cancel
Showing results for 
Show  only  | Search instead for 
Did you mean: 
andrew57jm
Visitor
Visitor
10,893 Views
Registered: ‎06-14-2012

qt 5.4.2 build problem

Jump to solution

I'm trying to follow the instructions for building Qt 5.4.2 and Qwt 6.1.2 as part of building the Zynz Base TRD 2015.4

 

The Qmake.conf file which is referenced by the xilinx document seems not to have been updated for the more recent Qt version. It refers to a qws.conf file which does not exist in 5.4.2 (but does in earlier versions) and seems to have an incorrect directory structure for the newer version of qt.

 

Has anyone successfully built Qt 5.4.2 and if so, can you suggest what changes are necessary to qmake.conf and qtplatformdefs.h to get it to build correctly.

 

Thanks. 

0 Kudos
1 Solution

Accepted Solutions
ckohn
Xilinx Employee
Xilinx Employee
20,851 Views
Registered: ‎12-08-2011

Hi andrew57jm,

 

can you please try the below qmake.conf instead? I have the feeling the file on the wiki got overwritten due to a naming conflict. I will follow up and get the file fixed on the wiki though.

 

Chris

 

--

 

#
# qmake configuration for building with arm-xilinx-linux-gnueabi-g++
#

MAKEFILE_GENERATOR = UNIX
CONFIG += incremental
QMAKE_INCREMENTAL_STYLE = sublib

 

include(../common/linux.conf)
include(../common/gcc-base-unix.conf)
include(../common/g++-unix.conf)

 

# modifications to g++.conf
QMAKE_CC = arm-xilinx-linux-gnueabi-gcc
QMAKE_CXX = arm-xilinx-linux-gnueabi-g++
QMAKE_LINK = arm-xilinx-linux-gnueabi-g++
QMAKE_LINK_SHLIB = arm-xilinx-linux-gnueabi-g++

 

# modifications to linux.conf
QMAKE_AR = arm-xilinx-linux-gnueabi-ar cqs
QMAKE_OBJCOPY = arm-xilinx-linux-gnueabi-objcopy
QMAKE_NM = arm-xilinx-linux-gnueabi-nm -P
QMAKE_STRIP = arm-xilinx-linux-gnueabi-strip


load(qt_config)

View solution in original post

0 Kudos
4 Replies
ckohn
Xilinx Employee
Xilinx Employee
20,852 Views
Registered: ‎12-08-2011

Hi andrew57jm,

 

can you please try the below qmake.conf instead? I have the feeling the file on the wiki got overwritten due to a naming conflict. I will follow up and get the file fixed on the wiki though.

 

Chris

 

--

 

#
# qmake configuration for building with arm-xilinx-linux-gnueabi-g++
#

MAKEFILE_GENERATOR = UNIX
CONFIG += incremental
QMAKE_INCREMENTAL_STYLE = sublib

 

include(../common/linux.conf)
include(../common/gcc-base-unix.conf)
include(../common/g++-unix.conf)

 

# modifications to g++.conf
QMAKE_CC = arm-xilinx-linux-gnueabi-gcc
QMAKE_CXX = arm-xilinx-linux-gnueabi-g++
QMAKE_LINK = arm-xilinx-linux-gnueabi-g++
QMAKE_LINK_SHLIB = arm-xilinx-linux-gnueabi-g++

 

# modifications to linux.conf
QMAKE_AR = arm-xilinx-linux-gnueabi-ar cqs
QMAKE_OBJCOPY = arm-xilinx-linux-gnueabi-objcopy
QMAKE_NM = arm-xilinx-linux-gnueabi-nm -P
QMAKE_STRIP = arm-xilinx-linux-gnueabi-strip


load(qt_config)

View solution in original post

0 Kudos
andrew57jm
Visitor
Visitor
10,831 Views
Registered: ‎06-14-2012

That fixed it.

Thanks!

0 Kudos
ckohn
Xilinx Employee
Xilinx Employee
10,823 Views
Registered: ‎12-08-2011

Can you please mark the topic as fixed?

 

Also, it seems like there is a namespace problem with our wiki. I need to upload the files with different names for the two Qt versions :/

 

There is another file that is affected, qwtconfig.pri. Stay put and I'll update the pages and file names. For now I'm posting the 6.1.2 version of this file below.

 

Chris

 

--

 

################################################################
# Qwt Widget Library
# Copyright (C) 1997 Josef Wilgen
# Copyright (C) 2002 Uwe Rathmann
#
# This library is free software; you can redistribute it and/or
# modify it under the terms of the Qwt License, Version 1.0
################################################################

QWT_VER_MAJ = 6
QWT_VER_MIN = 1
QWT_VER_PAT = 2
QWT_VERSION = $${QWT_VER_MAJ}.$${QWT_VER_MIN}.$${QWT_VER_PAT}

######################################################################
# Install paths
######################################################################

QWT_INSTALL_PREFIX = $$[QT_INSTALL_PREFIX]
QWT_INSTALL_DOCS = $${QWT_INSTALL_PREFIX}/doc
QWT_INSTALL_HEADERS = $${QWT_INSTALL_PREFIX}/include
QWT_INSTALL_LIBS = $${QWT_INSTALL_PREFIX}/lib

######################################################################
# Designer plugin
# creator/designer load designer plugins from certain default
# directories ( f.e the path below QT_INSTALL_PREFIX ) and the
# directories listed in the QT_PLUGIN_PATH environment variable.
# When using the path below QWT_INSTALL_PREFIX you need to
# add $${QWT_INSTALL_PREFIX}/plugins to QT_PLUGIN_PATH in the
# runtime environment of designer/creator.
######################################################################

QWT_INSTALL_PLUGINS = $${QWT_INSTALL_PREFIX}/plugins/designer

# linux distributors often organize the Qt installation
# their way and QT_INSTALL_PREFIX doesn't offer a good
# path. Also QT_INSTALL_PREFIX is only one of the default
# search paths of the designer - not the Qt creator

#QWT_INSTALL_PLUGINS = $$[QT_INSTALL_PREFIX]/plugins/designer

######################################################################
# Features
# When building a Qwt application with qmake you might want to load
# the compiler/linker flags, that are required to build a Qwt application
# from qwt.prf. Therefore all you need to do is to add "CONFIG += qwt"
# to your project file and take care, that qwt.prf can be found by qmake.
# ( see http://doc.trolltech.com/4.7/qmake-advanced-usage.html#adding-new-configuration-features )
# I recommend not to install the Qwt features together with the
# Qt features, because you will have to reinstall the Qwt features,
# with every Qt upgrade.
######################################################################

QWT_INSTALL_FEATURES = $${QWT_INSTALL_PREFIX}/features
# QWT_INSTALL_FEATURES = $$[QT_INSTALL_PREFIX]/features

######################################################################
# Build the static/shared libraries.
# If QwtDll is enabled, a shared library is built, otherwise
# it will be a static library.
######################################################################

QWT_CONFIG += QwtDll

######################################################################
# QwtPlot enables all classes, that are needed to use the QwtPlot
# widget.
######################################################################

QWT_CONFIG += QwtPlot

######################################################################
# QwtWidgets enables all classes, that are needed to use the all other
# widgets (sliders, dials, ...), beside QwtPlot.
######################################################################

QWT_CONFIG += QwtWidgets

######################################################################
# If you want to display svg images on the plot canvas, or
# export a plot to a SVG document
######################################################################

QWT_CONFIG += QwtSvg

######################################################################
# If you want to use a OpenGL plot canvas
######################################################################

#QWT_CONFIG += QwtOpenGL

######################################################################
# You can use the MathML renderer of the Qt solutions package to
# enable MathML support in Qwt. Because of license implications
# the ( modified ) code of the MML Widget solution is included and
# linked together with the QwtMathMLTextEngine into an own library.
# To use it you will have to add "CONFIG += qwtmathml"
# to your qmake project file.
######################################################################

#QWT_CONFIG += QwtMathML

######################################################################
# If you want to build the Qwt designer plugin,
# enable the line below.
# Otherwise you have to build it from the designer directory.
######################################################################

#QWT_CONFIG += QwtDesigner

######################################################################
# Compile all Qwt classes into the designer plugin instead
# of linking it against the shared Qwt library. Has no effect
# when QwtDesigner or QwtDll are not both enabled.
#
# On systems where rpath is supported ( all Unixoids ) the
# location of the installed Qwt library is compiled into the plugin,
# but on Windows it might be easier to have a self contained
# plugin to avoid any hassle with configuring the runtime
# environment of the designer/creator.
######################################################################

win32 {
QWT_CONFIG += QwtDesignerSelfContained
}

######################################################################
# If you want to auto build the examples, enable the line below
# Otherwise you have to build them from the examples directory.
######################################################################

#QWT_CONFIG += QwtExamples

######################################################################
# The playground is primarily intended for the Qwt development
# to explore and test new features. Nevertheless you might find
# ideas or code snippets that help for application development
# If you want to auto build the applications in playground, enable
# the line below.
# Otherwise you have to build them from the playground directory.
######################################################################

#QWT_CONFIG += QwtPlayground

######################################################################
# When Qt has been built as framework qmake wants
# to link frameworks instead of regular libs
######################################################################

macx:!static:CONFIG(qt_framework, qt_framework|qt_no_framework) {

QWT_CONFIG += QwtFramework
}

######################################################################
# Create and install pc files for pkg-config
# See http://www.freedesktop.org/wiki/Software/pkg-config/
######################################################################

unix {

#QWT_CONFIG += QwtPkgConfig
}

0 Kudos
ckohn
Xilinx Employee
Xilinx Employee
10,819 Views
Registered: ‎12-08-2011

I re-uploaded the files and updated the instructions as file renaming is now required. Please check the wiki.

0 Kudos